From c068a218eac02044cb5823abb1917051e1815b4f Mon Sep 17 00:00:00 2001
From: Lain Soykaf <lain@lain.com>
Date: Sun, 10 Dec 2023 18:57:46 +0400
Subject: [PATCH] Backup Tests: Split out async tests, use mox.

---
 config/test.exs                         |  2 +
 lib/pleroma/user/backup.ex              | 60 ++++++++++++++++---------
 test/pleroma/user/backup_async_test.exs | 51 +++++++++++++++++++++
 test/support/mocks.ex                   |  2 +
 4 files changed, 95 insertions(+), 20 deletions(-)
 create mode 100644 test/pleroma/user/backup_async_test.exs

diff --git a/config/test.exs b/config/test.exs
index 86604212d..1d121e5e9 100644
--- a/config/test.exs
+++ b/config/test.exs
@@ -145,6 +145,8 @@ config :pleroma, :config_impl, Pleroma.UnstubbedConfigMock
 
 config :pleroma, Pleroma.PromEx, disabled: true
 
+config Pleroma.User.Backup, :config_impl, Pleroma.UnstubbedConfigMock
+
 if File.exists?("./config/test.secret.exs") do
   import_config "test.secret.exs"
 else
diff --git a/lib/pleroma/user/backup.ex b/lib/pleroma/user/backup.ex
index 447fca2a1..c7359313a 100644
--- a/lib/pleroma/user/backup.ex
+++ b/lib/pleroma/user/backup.ex
@@ -35,6 +35,8 @@ defmodule Pleroma.User.Backup do
     timestamps()
   end
 
+  @config_impl Application.compile_env(__MODULE__, :config_impl, Pleroma.Config)
+
   def create(user, admin_id \\ nil) do
     with :ok <- validate_limit(user, admin_id),
          {:ok, backup} <- user |> new() |> Repo.insert() do
@@ -124,7 +126,10 @@ defmodule Pleroma.User.Backup do
     |> Repo.update()
   end
 
-  def process(%__MODULE__{} = backup) do
+  def process(
+        %__MODULE__{} = backup,
+        processor_module \\ __MODULE__.Processor
+      ) do
     set_state(backup, :running, 0)
 
     current_pid = self()
@@ -132,7 +137,7 @@ defmodule Pleroma.User.Backup do
     task =
       Task.Supervisor.async_nolink(
         Pleroma.TaskSupervisor,
-        __MODULE__,
+        processor_module,
         :do_process,
         [backup, current_pid]
       )
@@ -140,25 +145,8 @@ defmodule Pleroma.User.Backup do
     wait_backup(backup, backup.processed_number, task)
   end
 
-  def do_process(backup, current_pid) do
-    with {:ok, zip_file} <- export(backup, current_pid),
-         {:ok, %{size: size}} <- File.stat(zip_file),
-         {:ok, _upload} <- upload(backup, zip_file) do
-      backup
-      |> cast(
-        %{
-          file_size: size,
-          processed: true,
-          state: :complete
-        },
-        [:file_size, :processed, :state]
-      )
-      |> Repo.update()
-    end
-  end
-
   defp wait_backup(backup, current_processed, task) do
-    wait_time = Pleroma.Config.get([__MODULE__, :process_wait_time])
+    wait_time = @config_impl.get([__MODULE__, :process_wait_time])
 
     receive do
       {:progress, new_processed} ->
@@ -365,3 +353,35 @@ defmodule Pleroma.User.Backup do
     )
   end
 end
+
+defmodule Pleroma.User.Backup.ProcessorAPI do
+  @callback do_process(%Pleroma.User.Backup{}, pid()) ::
+              {:ok, %Pleroma.User.Backup{}} | {:error, any()}
+end
+
+defmodule Pleroma.User.Backup.Processor do
+  @behaviour Pleroma.User.Backup.ProcessorAPI
+
+  alias Pleroma.Repo
+  alias Pleroma.User.Backup
+
+  import Ecto.Changeset
+
+  @impl true
+  def do_process(backup, current_pid) do
+    with {:ok, zip_file} <- Backup.export(backup, current_pid),
+         {:ok, %{size: size}} <- File.stat(zip_file),
+         {:ok, _upload} <- Backup.upload(backup, zip_file) do
+      backup
+      |> cast(
+        %{
+          file_size: size,
+          processed: true,
+          state: :complete
+        },
+        [:file_size, :processed, :state]
+      )
+      |> Repo.update()
+    end
+  end
+end
diff --git a/test/pleroma/user/backup_async_test.exs b/test/pleroma/user/backup_async_test.exs
new file mode 100644
index 000000000..b0e965c5d
--- /dev/null
+++ b/test/pleroma/user/backup_async_test.exs
@@ -0,0 +1,51 @@
+# Pleroma: A lightweight social networking server
+# Copyright © 2017-2023 Pleroma Authors <https://pleroma.social/>
+# SPDX-License-Identifier: AGPL-3.0-only
+
+defmodule Pleroma.User.BackupAsyncTest do
+  use Pleroma.DataCase, async: true
+
+  import Pleroma.Factory
+  import Mox
+
+  alias Pleroma.User.Backup
+  alias Pleroma.User.Backup.ProcessorMock
+  alias Pleroma.UnstubbedConfigMock, as: ConfigMock
+
+  setup do
+    user = insert(:user, %{nickname: "cofe", name: "Cofe", ap_id: "http://cofe.io/users/cofe"})
+
+    {:ok, backup} = user |> Backup.new() |> Repo.insert()
+    %{backup: backup}
+  end
+
+  @tag capture_log: true
+  test "it handles unrecoverable exceptions", %{backup: backup} do
+    ProcessorMock
+    |> expect(:do_process, fn _, _ ->
+      raise "mock exception"
+    end)
+
+    ConfigMock
+    |> stub_with(Pleroma.Config)
+
+    {:error, %{backup: backup, reason: :exit}} = Backup.process(backup, ProcessorMock)
+
+    assert backup.state == :failed
+  end
+
+  @tag capture_log: true
+  test "it handles timeouts", %{backup: backup} do
+    ProcessorMock
+    |> expect(:do_process, fn _, _ ->
+      Process.sleep(:timer.seconds(4))
+    end)
+
+    ConfigMock
+    |> expect(:get, fn [Pleroma.User.Backup, :process_wait_time] -> :timer.seconds(2) end)
+
+    {:error, %{backup: backup, reason: :timeout}} = Backup.process(backup, ProcessorMock)
+
+    assert backup.state == :failed
+  end
+end
diff --git a/test/support/mocks.ex b/test/support/mocks.ex
index 9693095ba..b941f5bb3 100644
--- a/test/support/mocks.ex
+++ b/test/support/mocks.ex
@@ -29,3 +29,5 @@ Mox.defmock(Pleroma.ConfigMock, for: Pleroma.Config.Getting)
 Mox.defmock(Pleroma.UnstubbedConfigMock, for: Pleroma.Config.Getting)
 
 Mox.defmock(Pleroma.LoggerMock, for: Pleroma.Logging)
+
+Mox.defmock(Pleroma.User.Backup.ProcessorMock, for: Pleroma.User.Backup.ProcessorAPI)